home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
The Arsenal Files 8
/
The Arsenal Files Collection #8 (Arsenal Computer) (1996).ISO
/
g_quake
/
kuaqe2.zip
/
WEAPONS.QC
< prev
next >
Wrap
Text File
|
1996-10-06
|
41KB
|
1,836 lines
/*
Modified Weapons.QC for cool stuff by Eli
*/
float FLASHLIGHT_ON = 1;
float LASER_ON = 2;
float CHASECAM_ON = 4;
float FOOTSTEPS_ON = 8;
float SVC_SETVIEWPORT = 5;
float SVC_SETVIEWANGLES = 10;
void (entity targ, entity inflictor, entity attacker, float damage) T_Damage;
void () player_run;
void(entity bomb, entity attacker, float rad, entity ignore) T_RadiusDamage;
void(vector org, vector vel, float damage) SpawnBlood;
void() SuperDamageSound;
void (entity FlashlightOwner) FlashlightToggle;
void () FlashlightTrack;
void (entity LaserOwner) LaserToggle;
void () LaserTrack;
void () ChasecamToggle;
void () ChasecamTrack;
void (float opt) ChasecamRemove;
void () ChasecamRestart;
void (entity ChasecamOwner) ChasecamStart;
void () EntityRemover;
void () FlareTouch;
void () FlareFire;
void () FootstepsToggle;
void (vector src, vector dir, float punch, vector spread) ShellEject;
void () ChangeSkin;
void () W_FireFlame;
void () BurnSelf;
// called by worldspawn
void() W_Precache =
{
precache_model ("progs/laser.mdl"); // Enforcer laser for flare
precache_model ("progs/null.spr"); // Null sprite for invisibility
precache_sound ("misc/power.wav"); // new rocket explosion
precache_sound ("player/step.wav"); // Footsteps
precache_sound ("hknight/hit.wav"); // flamethrower
precache_sound ("weapons/r_exp3.wav"); // new rocket explosion
precache_sound ("weapons/rocket1i.wav"); // spike gun
precache_sound ("weapons/sgun1.wav");
precache_sound ("weapons/guncock.wav"); // player shotgun
precache_sound ("weapons/ric1.wav"); // ricochet (used in c code)
precache_sound ("weapons/ric2.wav"); // ricochet (used in c code)
precache_sound ("weapons/ric3.wav"); // ricochet (used in c code)
precache_sound ("weapons/spike2.wav"); // super spikes
precache_sound ("weapons/tink1.wav"); // spikes tink (used in c code)
precache_sound ("weapons/grenade.wav"); // grenade launcher
precache_sound ("weapons/bounce.wav"); // grenade bounce
precache_sound ("weapons/shotgn2.wav"); // super shotgun
precache_sound2 ("blob/land1.wav");
precache_sound ("plats/medplat1.wav");
precache_sound ("doors/ddoor1.wav");
precache_sound ("items/protect3.wav");
precache_sound ("items/damage3.wav");
};
float() crandom =
{
return 2*(random() - 0.5);
};
/*
================
W_FireAxe
================
*/
void() W_FireAxe =
{
local vector source;
local vector org;
source = self.origin + '0 0 16';
traceline (source, source + v_forward*64, FALSE, self);
if (trace_fraction == 1.0)
return;
org = trace_endpos - v_forward*4;
if (trace_ent.takedamage)
{
trace_ent.axhitme = 1;
SpawnBlood (org, '0 0 0', 20);
T_Damage (trace_ent, self, self, 20);
}
else
{ // hit wall
sound (self, CHAN_WEAPON, "player/axhit2.wav", 1, ATTN_NORM);
WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
WriteByte (MSG_BROADCAST, TE_GUNSHOT);
WriteCoord (MSG_BROADCAST, org_x);
WriteCoord (MSG_BROADCAST, org_y);
WriteCoord (MSG_BROADCAST, org_z);
}
};
//============================================================================
vector() wall_velocity =
{
local vector vel;
vel = normalize (self.velocity);
vel = normalize(vel + v_up*(random()- 0.5) + v_right*(random()- 0.5));
vel = vel + 2*trace_plane_normal;
vel = vel * 200;
return vel;
};
/*
================
SpawnMeatSpray
================
*/
void(vector org, vector vel) SpawnMeatSpray =
{
local entity missile, mpuff;
local vector org;
missile = spawn ();
missile.owner = self;
missile.movetype = MOVETYPE_BOUNCE;
missile.solid = SOLID_NOT;
makevectors (self.angles);
missile.velocity = vel;
missile.velocity_z = missile.velocity_z + 250 + 50*random();
missile.avelocity = '3000 1000 2000';
// set missile duration
missile.nextthink = time + 1;
missile.think = SUB_Remove;
setmodel (missile, "progs/zom_gib.mdl");
setsize (missile, '0 0 0', '0 0 0');
setorigin (missile, org);
};
/*
================
SpawnBlood
================
*/
void(vector org, vector vel, float damage) SpawnBlood =
{
particle (org, vel*0.1, 73, damage*2);
};
/*
================
spawn_touchblood
================
*/
void(float damage) spawn_touchblood =
{
local vector vel;
vel = wall_velocity () * 0.2;
SpawnBlood (self.origin + vel*0.01, vel, damage);
};
/*
================
SpawnChunk
================
*/
void(vector org, vector vel) SpawnChunk =
{
particle (org, vel*0.02, 0, 10);
};
/*
==============================================================================
MULTI-DAMAGE
Collects multiple small damages into a single damage
==============================================================================
*/
entity multi_ent;
float multi_damage;
void() ClearMultiDamage =
{
multi_ent = world;
multi_damage = 0;
};
void() ApplyMultiDamage =
{
if (!multi_ent)
return;
T_Damage (multi_ent, self, self, multi_damage);
};
void(entity hit, float damage) AddMultiDamage =
{
if (!hit)
return;
if (hit != multi_ent)
{
ApplyMultiDamage ();
multi_damage = damage;
multi_ent = hit;
}
else
multi_damage = multi_damage + damage;
};
/*
==============================================================================
BULLETS
==============================================================================
*/
/*
================
TraceAttack
================
*/
void(float damage, vector dir) TraceAttack =
{
local vector vel, org;
vel = normalize(dir + v_up*crandom() + v_right*crandom());
vel = vel + 2*trace_plane_normal;
vel = vel * 200;
org = trace_endpos - dir*4;
if (trace_ent.takedamage)
{
SpawnBlood (org, vel*0.2, damage);
AddMultiDamage (trace_ent, damage);
}
else
{
WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
WriteByte (MSG_BROADCAST, TE_GUNSHOT);
WriteCoord (MSG_BROADCAST, org_x);
WriteCoord (MSG_BROADCAST, org_y);
WriteCoord (MSG_BROADCAST, org_z);
}
};
/*
================
FireBullets
Used by shotgun, super shotgun, and enemy soldier firing
Go to the trouble of combining multiple pellets into a single damage call.
================
*/
void(float shotcount, vector dir, vector spread) FireBullets =
{
local vector direction;
local vector src;
makevectors(self.v_angle);
src = self.origin + v_forward*10;
src_z = self.absmin_z + self.size_z * 0.7;
ClearMultiDamage ();
while (shotcount > 0)
{
direction = dir + crandom()*spread_x*v_right + crandom()*spread_y*v_up;
traceline (src, src + direction*2048, FALSE, self);
if (trace_fraction != 1.0)
TraceAttack (4, direction);
shotcount = shotcount - 1;
}
ApplyMultiDamage ();
};
/*
================
W_FireShotgun
================
*/
void() W_FireShotgun =
{
local vector dir;
sound (self, CHAN_WEAPON, "weapons/guncock.wav", 1, ATTN_NORM);
self.punchangle_x = -2;
self.currentammo = self.ammo_shells = self.ammo_shells - 1;
dir = aim (self, 100000);
FireBullets (6, dir, '0.04 0.04 0');
// added for shell eject
ShellEject (self.origin + '0 0 16' + v_forward*3,dir, 200, '.5 .5 .5');
};
/*
================
W_FireSuperShotgun
================
*/
void() W_FireSuperShotgun =
{
local vector dir;
if (self.currentammo == 1)
{
W_FireShotgun ();
return;
}
sound (self ,CHAN_WEAPON, "weapons/shotgn2.wav", 1, ATTN_NORM);
self.punchangle_x = -4;
self.currentammo = self.ammo_shells = self.ammo_shells - 2;
dir = aim (self, 100000);
FireBullets (14, dir, '0.14 0.08 0');
ShellEject (self.origin + '0 0 16' + v_forward*3,dir, 400, '0.3 0.3 0.3');
ShellEject (self.origin + '0 0 16' + v_forward*3,dir, 400, '0.3 0.3 0.3');
};
/*
==============================================================================
ROCKETS
==============================================================================
*/
void() s_explode1 = [0, s_explode2] {};
void() s_explode2 = [1, s_explode3] {};
void() s_explode3 = [2, s_explode4] {};
void() s_explode4 = [3, s_explode5] {};
void() s_explode5 = [4, s_explode6] {};
void() s_explode6 = [5, SUB_Remove] {};
void() BecomeExplosion =
{
self.movetype = MOVETYPE_NONE;
self.velocity = '0 0 0';
self.touch = SUB_Null;
setmodel (self, "progs/s_explod.spr");
self.solid = SOLID_NOT;
s_explode1 ();
};
void() T_MissileTouch =
{
local float damg;
if (other == self.owner)
return; // don't explode on owner
if (pointcontents(self.origin) == CONTENT_SKY)
{
remove(self);
return;
}
damg = 100 + random()*20;
if (other.health)
{
if (other.classname == "monster_shambler")
damg = damg * 0.5; // mostly immune
T_Damage (other, self, self.owner, damg );
}
// don't do radius damage to the other, because all the damage
// was done in the impact
T_RadiusDamage (self, self.owner, 120, other);
// sound (self, CHAN_WEAPON, "weapons/r_exp3.wav", 1, ATTN_NORM);
self.origin = self.origin - 8*normalize(self.velocity);
WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
WriteByte (MSG_BROADCAST, TE_EXPLOSION);
WriteCoord (MSG_BROADCAST, self.origin_x);
WriteCoord (MSG_BROADCAST, self.origin_y);
WriteCoord (MSG_BROADCAST, self.origin_z);
BecomeExplosion ();
};
/*
================
W_FireRocket
================
*/
void() W_FireRocket =
{
local entity missile, mpuff;
self.currentammo = self.ammo_rockets = self.ammo_rockets - 1;
sound (self, CHAN_WEAPON, "weapons/sgun1.wav", 1, ATTN_NORM);
self.punchangle_x = -2;
missile = spawn ();
missile.owner = self;
missile.movetype = MOVETYPE_FLYMISSILE;
missile.solid = SOLID_BBOX;
// set missile speed
makevectors (self.v_angle);
missile.velocity = aim(self, 1000);
missile.velocity = missile.velocity * 1000;
missile.angles = vectoangles(missile.velocity);
missile.touch = T_MissileTouch;
// set missile duration
missile.nextthink = time + 5;
missile.think = SUB_Remove;
setmodel (missile, "progs/missile.mdl");
setsize (missile, '0 0 0', '0 0 0');
setorigin (missile, self.origin + v_forward*8 + '0 0 16');
};
/*
===============================================================================
LIGHTNING
===============================================================================
*/
/*
=================
LightningDamage
=================
*/
void(vector p1, vector p2, entity from, float damage) LightningDamage =
{
local entity e1, e2;
local vector f;
f = p2 - p1;
normalize (f);
f_x = 0 - f_y;
f_y = f_x;
f_z = 0;
f = f*16;
e1 = e2 = world;
traceline (p1, p2, FALSE, self);
if (trace_ent.takedamage)
{
particle (trace_endpos, '0 0 100', 225, damage*4);
T_Damage (trace_ent, from, from, damage);
if (self.classname == "player")
{
if (other.classname == "player")
trace_ent.velocity_z = trace_ent.velocity_z + 400;
}
}
e1 = trace_ent;
traceline (p1 + f, p2 + f, FALSE, self);
if (trace_ent != e1 && trace_ent.takedamage)
{
particle (trace_endpos, '0 0 100', 225, damage*4);
T_Damage (trace_ent, from, from, damage);
}
e2 = trace_ent;
traceline (p1 - f, p2 - f, FALSE, self);
if (trace_ent != e1 && trace_ent != e2 && trace_ent.takedamage)
{
particle (trace_endpos, '0 0 100', 225, damage*4);
T_Damage (trace_ent, from, from, damage);
}
};
void() W_FireLightning =
{
local vector org;
if (self.ammo_cells < 1)
{
self.weapon = W_BestWeapon ();
W_SetCurrentAmmo ();
return;
}
// explode if under water
if (self.waterlevel > 1)
{
T_RadiusDamage (self, self, 35*self.ammo_cells, world);
self.ammo_cells = 0;
W_SetCurrentAmmo ();
return;
}
if (self.t_width < time)
{
sound (self, CHAN_WEAPON, "weapons/lhit.wav", 1, ATTN_NORM);
self.t_width = time + 0.6;
}
self.punchangle_x = -2;
self.currentammo = self.ammo_cells = self.ammo_cells - 1;
org = self.origin + '0 0 16';
traceline (org, org + v_forward*600, TRUE, self);
WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
WriteByte (MSG_BROADCAST, TE_LIGHTNING2);
WriteEntity (MSG_BROADCAST, self);
WriteCoord (MSG_BROADCAST, org_x);
WriteCoord (MSG_BROADCAST, org_y);
WriteCoord (MSG_BROADCAST, org_z);
WriteCoord (MSG_BROADCAST, trace_endpos_x);
WriteCoord (MSG_BROADCAST, trace_endpos_y);
WriteCoord (MSG_BROADCAST, trace_endpos_z);
LightningDamage (self.origin, trace_endpos + v_forward*4, self, 30);
};
//=============================================================================
void() GrenadeExplode =
{
T_RadiusDamage (self, self.owner, 120, world);
WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
WriteByte (MSG_BROADCAST, TE_EXPLOSION);
WriteCoord (MSG_BROADCAST, self.origin_x);
WriteCoord (MSG_BROADCAST, self.origin_y);
WriteCoord (MSG_BROADCAST, self.origin_z);
BecomeExplosion ();
};
void() GrenadeTouch =
{
if (other == self.owner)
return; // don't explode on owner
if (other.takedamage == DAMAGE_AIM)
{
GrenadeExplode();
return;
}
sound (self, CHAN_WEAPON, "weapons/bounce.wav", 1, ATTN_NORM); // bounce sound
if (self.velocity == '0 0 0')
self.avelocity = '0 0 0';
};
/*
================
W_FireGrenade
================
*/
void() W_FireGrenade =
{
local entity missile, mpuff;
self.currentammo = self.ammo_rockets = self.ammo_rockets - 1;
sound (self, CHAN_WEAPON, "weapons/grenade.wav", 1, ATTN_NORM);
self.punchangle_x = -2;
missile = spawn ();
missile.owner = self;
missile.movetype = MOVETYPE_BOUNCE;
missile.solid = SOLID_BBOX;
missile.classname = "grenade";
// set missile speed
makevectors (self.v_angle);
if (self.v_angle_x)
missile.velocity = v_forward*600 + v_up * 200 + crandom()*v_right*10 + crandom()*v_up*10;
else
{
missile.velocity = aim(self, 10000);
missile.velocity = missile.velocity * 600;
missile.velocity_z = 200;
}
missile.avelocity = '300 300 300';
missile.angles = vectoangles(missile.velocity);
missile.touch = GrenadeTouch;
// set missile duration
missile.nextthink = time + 2.5;
missile.think = GrenadeExplode;
setmodel (missile, "progs/grenade.mdl");
setsize (missile, '0 0 0', '0 0 0');
setorigin (missile, self.origin);
};
//=============================================================================
void() spike_touch;
void() superspike_touch;
/*
===============
launch_spike
Used for both the player and the ogre
===============
*/
void(vector org, vector dir) launch_spike =
{
newmis = spawn ();
newmis.owner = self;
newmis.movetype = MOVETYPE_FLYMISSILE;
newmis.solid = SOLID_BBOX;
newmis.angles = vectoangles(dir);
newmis.touch = spike_touch;
newmis.classname = "spike";
newmis.think = SUB_Remove;
newmis.nextthink = time + 6;
setmodel (newmis, "progs/spike.mdl");
setsize (newmis, VEC_ORIGIN, VEC_ORIGIN);
setorigin (newmis, org);
newmis.velocity = dir * 1000;
};
void() W_FireSuperSpikes =
{
local vector dir;
local entity old;
sound (self, CHAN_WEAPON, "weapons/spike2.wav", 1, ATTN_NORM);
self.attack_finished = time + 0.2;
self.currentammo = self.ammo_nails = self.ammo_nails - 2;
dir = aim (self, 1000);
launch_spike (self.origin + '0 0 16', dir);
newmis.touch = superspike_touch;
setmodel (newmis, "progs/s_spike.mdl");
setsize (newmis, VEC_ORIGIN, VEC_ORIGIN);
self.punchangle_x = -2;
};
void(float ox) W_FireSpikes =
{
local vector dir;
local entity old;
makevectors (self.v_angle);
if (self.ammo_nails >= 2 && self.weapon == IT_SUPER_NAILGUN)
{
W_FireSuperSpikes ();
return;
}
if (self.ammo_nails < 1)
{
self.weapon = W_BestWeapon ();
W_SetCurrentAmmo ();
return;
}
sound (self, CHAN_WEAPON, "weapons/rocket1i.wav", 1, ATTN_NORM);
self.attack_finished = time + 0.2;
self.currentammo = self.ammo_nails = self.ammo_nails - 1;
dir = aim (self, 1000);
launch_spike (self.origin + '0 0 16' + v_right*ox, dir);
self.punchangle_x = -2;
};
.float hit_z;
void() spike_touch =
{
local float rand;
if (other == self.owner)
return;
if (other.solid == SOLID_TRIGGER)
return; // trigger field, do nothing
if (pointcontents(self.origin) == CONTENT_SKY)
{
remove(self);
return;
}
// hit something that bleeds
if (other.takedamage)
{
spawn_touchblood (9);
T_Damage (other, self, self.owner, 9);
}
else
{
WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
if (self.classname == "wizspike")
WriteByte (MSG_BROADCAST, TE_WIZSPIKE);
else if (self.classname == "knightspike")
WriteByte (MSG_BROADCAST, TE_KNIGHTSPIKE);
else
WriteByte (MSG_BROADCAST, TE_SPIKE);
WriteCoord (MSG_BROADCAST, self.origin_x);
WriteCoord (MSG_BROADCAST, self.origin_y);
WriteCoord (MSG_BROADCAST, self.origin_z);
}
remove(self);
};
void() superspike_touch =
{
local float rand;
if (other == self.owner)
return;
if (other.solid == SOLID_TRIGGER)
return; // trigger field, do nothing
if (pointcontents(self.origin) == CONTENT_SKY)
{
remove(self);
return;
}
// hit something that bleeds
if (other.takedamage)
{
spawn_touchblood (18);
T_Damage (other, self, self.owner, 18);
}
else
{
WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
WriteByte (MSG_BROADCAST, TE_SUPERSPIKE);
WriteCoord (MSG_BROADCAST, self.origin_x);
WriteCoord (MSG_BROADCAST, self.origin_y);
WriteCoord (MSG_BROADCAST, self.origin_z);
}
remove(self);
};
/*
===============================================================================
PLAYER WEAPON USE
===============================================================================
*/
void() W_SetCurrentAmmo =
{
player_run (); // get out of any weapon firing states
self.items = self.items - ( self.items & (IT_SHELLS | IT_NAILS | IT_ROCKETS | IT_CELLS) );
if (self.weapon == IT_AXE)
{
self.currentammo = 0;
self.weaponmodel = "progs/v_axe.mdl";
self.weaponframe = 0;
}
else if (self.weapon == IT_MORNINGSTAR)
{
self.currentammo = 0;
self.weaponmodel = "progs/v_star.mdl";
self.weaponframe = 0;
}
else if (self.weapon == IT_SHOTGUN)
{
self.currentammo = self.ammo_shells;
self.weaponmodel = "progs/v_shot.mdl";
self.weaponframe = 0;
self.items = self.items | IT_SHELLS;
}
else if (self.weapon == IT_SUPER_SHOTGUN)
{
self.currentammo = self.ammo_shells;
self.weaponmodel = "progs/v_shot2.mdl";
self.weaponframe = 0;
self.items = self.items | IT_SHELLS;
}
else if (self.weapon == IT_NAILGUN)
{
self.currentammo = self.ammo_nails;
self.weaponmodel = "progs/v_nail.mdl";
self.weaponframe = 0;
self.items = self.items | IT_NAILS;
}
else if (self.weapon == IT_SUPER_NAILGUN)
{
self.currentammo = self.ammo_nails;
self.weaponmodel = "progs/v_nail2.mdl";
self.weaponframe = 0;
self.items = self.items | IT_NAILS;
}
else if (self.weapon == IT_GRENADE_LAUNCHER)
{
self.currentammo = self.ammo_rockets;
self.weaponmodel = "progs/v_rock.mdl";
self.weaponframe = 0;
self.items = self.items | IT_ROCKETS;
}
else if (self.weapon == IT_ROCKET_LAUNCHER)
{
self.currentammo = self.ammo_rockets;
self.weaponmodel = "progs/v_rock2.mdl";
self.weaponframe = 0;
self.items = self.items | IT_ROCKETS;
}
else if (self.weapon == IT_FLAMETHROWER)
{
self.currentammo = self.ammo_shells;
self.weaponmodel = "progs/v_rock.mdl";
self.weaponframe = 0;
self.items = self.items | IT_SHELLS;
}
else if (self.weapon == IT_LIGHTNING)
{
self.currentammo = self.ammo_cells;
self.weaponmodel = "progs/v_light.mdl";
self.weaponframe = 0;
self.items = self.items | IT_CELLS;
}
else
{
self.currentammo = 0;
self.weaponmodel = "";
self.weaponframe = 0;
}
};
float() W_BestWeapon =
{
local float it;
it = self.items;
if(self.ammo_cells >= 1 && (it & IT_LIGHTNING) )
return IT_LIGHTNING;
else if(self.ammo_nails >= 2 && (it & IT_SUPER_NAILGUN) )
return IT_SUPER_NAILGUN;
else if(self.ammo_shells >= 2 && (it & IT_SUPER_SHOTGUN) )
return IT_SUPER_SHOTGUN;
else if(self.ammo_nails >= 1 && (it & IT_NAILGUN) )
return IT_NAILGUN;
else if(self.ammo_shells >= 1 && (it & IT_SHOTGUN) )
return IT_SHOTGUN;
/*
if(self.ammo_rockets >= 1 && (it & IT_ROCKET_LAUNCHER) )
return IT_ROCKET_LAUNCHER;
else if(self.ammo_rockets >= 1 && (it & IT_GRENADE_LAUNCHER) )
return IT_GRENADE_LAUNCHER;
*/
return IT_AXE;
};
float() W_CheckNoAmmo =
{
if (self.currentammo > 0)
return TRUE;
if ((self.weapon == IT_AXE) || (self.weapon == IT_MORNINGSTAR))
return TRUE;
self.weapon = W_BestWeapon ();
W_SetCurrentAmmo ();
// drop the weapon down
return FALSE;
};
/*
============
W_Attack
An attack impulse can be triggered now
============
*/
void() player_axe1;
void() player_axeb1;
void() player_axec1;
void() player_axed1;
void() player_shot1;
void() player_nail1;
void() player_light1;
void() player_rocket1;
void() player_chain1;
void() player_chain3;
void() W_Attack =
{
local float r;
if (!W_CheckNoAmmo ())
return;
makevectors (self.v_angle); // calculate forward angle for velocity
self.show_hostile = time + 1; // wake monsters up
if (self.weapon == IT_AXE)
{
sound (self, CHAN_WEAPON, "weapons/ax1.wav", 1, ATTN_NORM);
r = random();
if (r < 0.25)
player_axe1 ();
else if (r<0.5)
player_axeb1 ();
else if (r<0.75)
player_axec1 ();
else
player_axed1 ();
self.attack_finished = time + 0.5;
}
else if (self.weapon == IT_MORNINGSTAR)
{
if (!self.hook_out)
player_chain1();
else
player_chain3();
self.attack_finished = time + 0.1;
}
else if (self.weapon == IT_SHOTGUN)
{
player_shot1 ();
W_FireShotgun ();
self.attack_finished = time + 0.5;
}
else if (self.weapon == IT_SUPER_SHOTGUN)
{
player_shot1 ();
W_FireSuperShotgun ();
self.attack_finished = time + 0.7;
}
else if (self.weapon == IT_NAILGUN)
{
player_nail1 ();
}
else if (self.weapon == IT_SUPER_NAILGUN)
{
player_nail1 ();
}
else if (self.weapon == IT_GRENADE_LAUNCHER)
{
player_rocket1();
W_FireGrenade();
self.attack_finished = time + 0.6;
}
else if (self.weapon == IT_ROCKET_LAUNCHER)
{
player_rocket1();
W_FireRocket();
self.attack_finished = time + 0.8;
}
else if (self.weapon == IT_FLAMETHROWER)
{
player_shot1();
W_FireFlame ();
if (self.waterlevel >2)
self.attack_finished = time + 1;
else
self.attack_finished = time + 0.1;
}
else if (self.weapon == IT_LIGHTNING)
{
player_light1();
self.attack_finished = time + 0.1;
sound (self, CHAN_AUTO, "weapons/lstart.wav", 1, ATTN_NORM);
}
};
/*
============
W_ChangeWeapon
============
*/
void() W_ChangeWeapon =
{
local float it, am, fl;
it = self.items;
am = 0;
if (self.impulse == 1)
{
if (self.weapon == IT_AXE)
{
fl = IT_MORNINGSTAR;
if ((!deathmatch) && (!coop))
sprint (self, "Cheater\n");
}
else
fl = IT_AXE;
}
else if (self.impulse == 2)
{
fl = IT_SHOTGUN;
if (self.ammo_shells < 1)
am = 1;
}
else if (self.impulse == 3)
{
fl = IT_SUPER_SHOTGUN;
if (self.ammo_shells < 2)
am = 1;
}
else if (self.impulse == 4)
{
fl = IT_NAILGUN;
if (self.ammo_nails < 1)
am = 1;
}
else if (self.impulse == 5)
{
fl = IT_SUPER_NAILGUN;
if (self.ammo_nails < 2)
am = 1;
}
else if (self.impulse == 6)
{
if (self.weapon != IT_GRENADE_LAUNCHER && self.ammo_rockets > 0)
{
fl = IT_GRENADE_LAUNCHER;
if (self.ammo_rockets < 1)
am = 1;
}
else if (self.ammo_shells > 1)
{
fl = IT_FLAMETHROWER;
if (self.ammo_shells < 1)
am = 1;
}
else am = 1;
}
else if (self.impulse == 7)
{
fl = IT_ROCKET_LAUNCHER;
if (self.ammo_rockets < 1)
am = 1;
}
else if (self.impulse == 8)
{
fl = IT_LIGHTNING;
if (self.ammo_cells < 1)
am = 1;
}
else if (self.impulse == 50)
{
fl = IT_FLAMETHROWER;
if (self.ammo_rockets < 1)
am = 1;
}
self.impulse = 0;
if (!(self.items & fl))
{ // don't have the weapon or the ammo
sprint (self, "no weapon.\n");
return;
}
if (am)
{ // don't have the ammo
sprint (self, "not enough ammo.\n");
return;
}
//
// set weapon, set ammo
//
self.weapon = fl;
if (self.weapon == IT_FLAMETHROWER)
sprint (self, "Flamethrower\n");
if (self.weapon == IT_GRENADE_LAUNCHER)
sprint (self, "Grenade Launcher\n");
W_SetCurrentAmmo ();
};
/*
============
CheatCommand
============
*/
void() CheatCommand =
{
if (deathmatch || coop)
return;
self.ammo_rockets = 100;
self.ammo_nails = 200;
self.ammo_shells = 100;
self.items = self.items |
IT_AXE |
IT_SHOTGUN |
IT_SUPER_SHOTGUN |
IT_NAILGUN |
IT_SUPER_NAILGUN |
IT_GRENADE_LAUNCHER |
IT_FLAMETHROWER |
IT_ROCKET_LAUNCHER |
IT_KEY1 | IT_KEY2;
self.ammo_cells = 200;
self.items = self.items | IT_LIGHTNING;
self.weapon = IT_ROCKET_LAUNCHER;
self.impulse = 0;
W_SetCurrentAmmo ();
};
/*
============
CycleWeaponCommand
Go to the next weapon with ammo
============
*/
void() CycleWeaponCommand =
{
local float it, am;
it = self.items;
self.impulse = 0;
while (1)
{
am = 0;
if (self.weapon == IT_LIGHTNING)
{
self.weapon = IT_AXE;
}
else if (self.weapon == IT_AXE)
{
self.weapon = IT_MORNINGSTAR;
}
else if (self.weapon == IT_MORNINGSTAR)
{
self.weapon = IT_SHOTGUN;
if (self.ammo_shells < 1)
am = 1;
}
else if (self.weapon == IT_SHOTGUN)
{
self.weapon = IT_SUPER_SHOTGUN;
if (self.ammo_shells < 2)
am = 1;
}
else if (self.weapon == IT_SUPER_SHOTGUN)
{
self.weapon = IT_NAILGUN;
if (self.ammo_nails < 1)
am = 1;
}
else if (self.weapon == IT_NAILGUN)
{
self.weapon = IT_SUPER_NAILGUN;
if (self.ammo_nails < 2)
am = 1;
}
else if (self.weapon == IT_SUPER_NAILGUN)
{
self.weapon = IT_GRENADE_LAUNCHER;
if (self.ammo_rockets < 1)
am = 1;
}
else if (self.weapon == IT_GRENADE_LAUNCHER)
{
self.weapon = IT_FLAMETHROWER;
if (self.ammo_rockets < 1)
am = 1;
}
else if (self.weapon == IT_FLAMETHROWER)
{
self.weapon = IT_ROCKET_LAUNCHER;
if (self.ammo_rockets < 1)
am = 1;
}
else if (self.weapon == IT_ROCKET_LAUNCHER)
{
self.weapon = IT_LIGHTNING;
if (self.ammo_cells < 1)
am = 1;
}
if ( (self.items & self.weapon) && am == 0)
{
if (self.weapon == IT_FLAMETHROWER)
sprint(self,"Flamethrower\n");
else if (self.weapon == IT_GRENADE_LAUNCHER)
sprint(self,"Grenade Launcher\n");
W_SetCurrentAmmo ();
return;
}
}
};
/*
============
ServerflagsCommand
Just for development
============
*/
void() ServerflagsCommand =
{
serverflags = serverflags * 2 + 1;
};
void() QuadCheat =
{
if (deathmatch || coop)
return;
self.super_time = 1;
self.super_damage_finished = time + 60;
self.items = self.items | IT_QUAD;
dprint ("quad cheat\n");
};
/*
============
ImpulseCommands
============
*/
void() ImpulseCommands =
{
if (self.impulse >= 1 && self.impulse <= 8)
W_ChangeWeapon ();
if (self.impulse == 9)
CheatCommand ();
if (self.impulse == 10)
CycleWeaponCommand ();
if (self.impulse == 11)
ServerflagsCommand ();
if (self.impulse == 15)
FlareFire ();
if (self.impulse == 16)
EntityRemover ();
if (self.impulse == 255)
QuadCheat ();
if (self.impulse == 12)
FlashlightToggle (self);
if (self.impulse == 13)
LaserToggle (self);
if (self.impulse == 14)
ChasecamToggle ();
if (self.impulse == 17)
FootstepsToggle ();
if ((self.impulse == 18) || (self.impulse == 19))
ChangeSkin ();
if (self.impulse == 187)
BurnSelf ();
self.impulse = 0;
};
/*
============
W_WeaponFrame
Called every frame so impulse events can be handled as well as possible
============
*/
void() W_WeaponFrame =
{
if (time < self.attack_finished)
return;
ImpulseCommands ();
// check for attack
if (self.button0)
{
SuperDamageSound ();
W_Attack ();
}
};
/*
========
SuperDamageSound
Plays sound if needed
========
*/
void() SuperDamageSound =
{
if (self.super_damage_finished > time)
{
if (self.super_sound < time)
{
self.super_sound = time + 1;
sound (self, CHAN_BODY, "items/damage3.wav", 1, ATTN_NORM);
}
}
return;
};
/*
======================
Flashlight Code by Eli
======================
*/
void() FlashlightTrack =
{
local vector src,
dir;
if (!(self.owner.speed & FLASHLIGHT_ON))
{
remove(self);
return;
}
makevectors (self.owner.v_angle);
src = self.owner.origin + '0 0 16' + v_forward * 10;
dir = aim(self.owner, 100000);
traceline (src, src + dir * 2048, FALSE, self.owner);
if (trace_fraction != 1.0)
src = trace_endpos - dir*4;
setorigin (self, src);
self.nextthink = time + 0.1;
};
void(entity FlashlightOwner) FlashlightToggle =
{
local entity Flashlight;
if ((self.speed & FLASHLIGHT_ON))
self.speed = self.speed - FLASHLIGHT_ON;
else
{
self.speed = self.speed | FLASHLIGHT_ON;
Flashlight = spawn();
Flashlight.owner = FlashlightOwner;
Flashlight.movetype = MOVETYPE_NONE;
Flashlight.solid = SOLID_NOT;
setmodel (Flashlight, "progs/null.spr");
setsize (Flashlight, VEC_ORIGIN, VEC_ORIGIN);
setorigin (Flashlight, self.owner.origin);
Flashlight.nextthink = time + 0.1;
Flashlight.think = FlashlightTrack;
Flashlight.effects = EF_DIMLIGHT;
}
return;
};
/*
End Flashlight Code
*/
/*
=============================
Laser Targeting System by Eli
=============================
*/
void () LaserTrack =
{
local vector src,
dir;
if (!(self.owner.speed & LASER_ON))
{
remove (self);
return;
}
makevectors (self.owner.v_angle);
src = self.owner.origin + '0 0 16' + v_forward * 10;
dir = aim(self.owner, 100000);
traceline (src, src + dir * 320, FALSE, self.owner);
src = 0.1 * src + 0.9 * trace_endpos;
setorigin (self, src);
self.nextthink = time + 0.1;
};
void (entity LaserOwner) LaserToggle =
{
local entity Laser;
if ((LaserOwner.speed & LASER_ON))
{
LaserOwner.speed = LaserOwner.speed - LASER_ON;
}
else
{
LaserOwner.speed = LaserOwner.speed | LASER_ON;
Laser = spawn ();
Laser.owner = LaserOwner;
Laser.movetype = MOVETYPE_NONE;
Laser.solid = SOLID_NOT;
setmodel (Laser, "progs/s_bubble.spr");
setsize (Laser, VEC_ORIGIN, VEC_ORIGIN);
setorigin (Laser, self.owner.origin);
Laser.nextthink = time + 0.1;
Laser.think = LaserTrack;
}
return;
};
/*
End Laser Targeting Code
*/
/*
===============
ChaseCam by Eli
===============
*/
float ChasecamDistance = 72, ChasecamZ = 16;
// called either by player or chase cam entities (to restart)
void (entity ChasecamOwner) ChasecamStart =
{
local entity Chasecam;
ChasecamOwner.speed = ChasecamOwner.speed | CHASECAM_ON;
Chasecam = spawn ();
Chasecam.owner = ChasecamOwner;
Chasecam.solid = SOLID_NOT;
Chasecam.movetype = MOVETYPE_FLYMISSILE;
Chasecam.angles = Chasecam.owner.angles;
setmodel (Chasecam, "progs/null.spr");
setsize (Chasecam, '0 0 0', '0 0 0');
setorigin (Chasecam, Chasecam.owner.origin);
Chasecam.classname = "Chasecam";
Chasecam.nextthink = time + 0.1;
Chasecam.think = ChasecamTrack;
msg_entity = Chasecam.owner; // target of message
WriteByte (MSG_ONE, SVC_SETVIEWPORT);
WriteEntity (MSG_ONE, Chasecam); // view port
};
// secondary think function for cam entities
void () ChasecamRestart =
{
self.nextthink = time + 0.1;
if (self.owner.health <= 0)
{
remove (self);
return;
}
if (self.owner.waterlevel)
return;
ChasecamStart (self.owner);
remove (self);
};
// called only by chase cam entities.
// opt values:
// TRUE = remove completely
// FALSE = remove view but keep alive with ChasecamRestart();
void (float opt) ChasecamRemove =
{
if ((self.owner.speed & CHASECAM_ON))
self.owner.speed = self.owner.speed - CHASECAM_ON;
setmodel (self, "progs/null.spr");
self.velocity = '0 0 0';
msg_entity = self.owner; // target of message
WriteByte (MSG_ONE, SVC_SETVIEWPORT);
WriteEntity (MSG_ONE, self.owner); // view port
if (!opt)
{
self.nextthink = time + 0.1;
self.think = ChasecamRestart;
}
else
remove (self);
};
// main think function for cam entities
// self.ammo_nails = hang-up flag
void() ChasecamTrack =
{
local vector spot2,
dir;
local float dist,
cap;
self.nextthink = time + 0.1;
if (!(self.owner.speed & CHASECAM_ON))
{
ChasecamRemove (TRUE);
return;
}
if (self.owner.waterlevel)
{
ChasecamRemove (FALSE);
return;
}
makevectors (self.owner.v_angle);
// Set initial spot before clipping, compensating for looking up
// and down so the player doesn't block the view
spot2 = self.owner.origin - (v_forward * self.ammo_shells);
spot2_z = spot2_z + ChasecamZ;
if (self.owner.v_angle_x < 0)
spot2 = spot2 - self.owner.v_angle_x * 0.6 * v_up;
if (self.owner.v_angle_x > 0)
spot2 = spot2 + self.owner.v_angle_x * 0.6 * v_up;
traceline (self.owner.origin, spot2, TRUE, self.owner);
self.ammo_shells = vlen (trace_endpos - self.owner.origin);
spot2 = trace_endpos + (v_forward * 2);
traceline (spot2, spot2 + '0 0 32', TRUE, self.owner );
if (trace_fraction < 1 )
spot2 = trace_endpos - '0 0 32';
dir = normalize (spot2 - self.origin);
dist = vlen (spot2 - self.origin);
traceline (self.origin, spot2, TRUE, self.owner);
if (trace_fraction == 1)
{
self.angles = self.owner.angles;
cap = dist * 0.2;
if (cap > 5.2)
self.velocity = dir * dist * 5.2;
else if (cap > 1)
self.velocity = dir * dist * cap;
else
self.velocity = dir * dist;
if ((vlen(self.owner.origin - self.origin)) < 30)
{
self.velocity = self.velocity * 2;
}
}
else
setorigin (self, spot2);
self.ammo_shells = self.ammo_shells + 4;
if (self.ammo_shells > ChasecamDistance)
self.ammo_shells = ChasecamDistance;
// respawn if missile ent. get's hung up
if (self.oldorigin == self.origin)
{
if (dist > 30)
self.ammo_nails = self.ammo_nails + 1;
}
if (self.ammo_nails > 3)
{
ChasecamStart (self.owner);
remove (self);
return;
}
self.oldorigin = self.origin;
};
void () ChasecamToggle =
{
if ((self.speed & CHASECAM_ON))
{
cvar_set ("scr_ofsx", "-2");
cvar_set ("scr_ofsy", "2");
cvar_set ("r_drawviewmodel", "1");
self.speed = self.speed - CHASECAM_ON;
}
else
{
cvar_set ("scr_ofsx", "0");
cvar_set ("scr_ofsy", "0");
cvar_set ("r_drawviewmodel", "0");
ChasecamStart (self);
}
};
/*
End Chasecam Code
*/
/*
=====================
Entity Remover by Eli
=====================
*/
void () EntityRemover =
{
local vector src, dir;
sound (self, CHAN_WEAPON, "weapons/grenade.wav", 1, ATTN_NORM);
makevectors (self.v_angle);
self.attack_finished = time + 0.5;
dir = aim (self, 100000);
src = self.origin + '0 0 16' + v_forward * 10;
traceline (src, src + dir * 2048, FALSE, self);
if (trace_ent != world)
remove (trace_ent);
};
/*
End Entity Remover Code
*/
/*
================
Flare Gun by Eli
================
*/
void () FlareFire =
{
local entity Flare;
makevectors (self.v_angle);
sound (self, CHAN_WEAPON, "weapons/grenade.wav", 1, ATTN_NORM);
self.attack_finished = time + 0.5;
self.punchangle_x = -2;
Flare = spawn ();
Flare.owner = self;
Flare.movetype = MOVETYPE_FLYMISSILE;
Flare.solid = SOLID_BBOX;
Flare.velocity = aim (self, 1000);
Flare.velocity = Flare.velocity * 1000;
Flare.angles = vectoangles (Flare.velocity);
Flare.touch = FlareTouch;
Flare.classname = "Flare";
Flare.think = SUB_Remove;
Flare.nextthink = time + 7;
setmodel (Flare, "progs/laser.mdl");
setsize (Flare, VEC_ORIGIN, VEC_ORIGIN);
setorigin (Flare, self.origin + '0 0 16');
Flare.effects = EF_DIMLIGHT;
};
void () FlareTouch =
{
local float rand;
if (other == self.owner)
return;
if (other.classname == "door" || other.classname == "plat")
{
remove (self);
return;
}
if (other.solid == SOLID_TRIGGER)
return;
if (other.takedamage)
{
spawn_touchblood (2);
T_Damage (other, self, self.owner, 1);
remove (self);
return;
}
self.movetype = MOVETYPE_NONE;
self.solid = SOLID_NOT;
self.origin = self.origin - self.velocity * 0.005;
self.velocity = '0 0 0';
self.touch = SUB_Null;
};
/*
End Flare Gun Code
*/
/*
Footsteps Code
*/
void () FootstepsToggle =
{
if ((self.speed & FOOTSTEPS_ON))
self.speed = self.speed - FOOTSTEPS_ON;
else
self.speed = self.speed | FOOTSTEPS_ON;
};
// End Footsteps Code
/*
========================
Eject shells code by Eli
========================
*/
void (vector src, vector dir, float punch, vector spread) ShellEject =
{
local float flip;
local vector transform;
local entity shell;
shell = spawn ();
shell.owner = self;
shell.movetype = MOVETYPE_BOUNCE;
shell.solid = SOLID_BBOX;
shell.angles = vectoangles (dir);
shell.think = SUB_Remove;
shell.nextthink = time + 5;
setmodel (shell, "progs/shelcase.mdl");
setsize (shell, VEC_ORIGIN, VEC_ORIGIN);
setorigin (shell, src);
flip = crandom ();
spread_x = spread_x * flip;
flip = crandom ();
spread_y = spread_y * flip;
flip = crandom ();
spread_z = spread_z * flip;
transform_x = dir_y + spread_x;
transform_y = 0 - dir_x + spread_y;
transform_z = dir_z + spread_z;
shell.velocity = transform * punch;
flip = random ();
if (flip < 0.25)
shell.avelocity = '300 300 300';
else if (flip < 0.5)
shell.avelocity = '150 300 100';
else if (flip < 0.75)
shell.avelocity = '200 100 0';
else
shell.avelocity = '400 200 100';
};
/*
End Shell Eject Code
*/
/*
====================
Multiskin Code Start
====================
*/
void () ChangeSkin =
{
if (self.impulse == 18)
self.skin = self.skin + 1;
if (self.impulse == 19)
self.skin = self.skin - 1;
dprint ("Skin Changed");
};
/*
End Multiskin Code
*/